delphi – 在pascal中动态分配匿名函数

我希望能够在pascal中动态生成弹出菜单.

我还希望能够为每个菜单项动态分配OnClick处理程序.

这是我以前在C#中可以做的事情,这是我在pascal中的尝试.

菜单项onClick事件处理程序需要属于一个Object对象,所以我为此创建了一个容器对象.

这是我的代码：

unit Unit1;

interface

uses
  Winapi.Windows,Winapi.Messages,System.SysUtils,System.Variants,System.Classes,Vcl.Graphics,Vcl.Controls,Vcl.Forms,Vcl.Dialogs,Vcl.StdCtrls,Vcl.Menus;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  TFoo = class
    public
      Bar : String;
      Val : Integer;
  end;

  TNotifyEventWrapper = class
    private
      FProc: TProc<TObject>;
      I : Integer;
    public
      constructor Create(Proc: TProc<TObject>);
    published
      procedure Event(Sender: TObject);
  end;

var
  Form1: TForm1;
  NE : TNotifyEventWrapper;

implementation

{$R *.dfm}

constructor TNotifyEventWrapper.Create(Proc: TProc<TObject>);
begin
    inherited Create;
    FProc := Proc;
end;

procedure TNotifyEventWrapper.Event(Sender: TObject);
begin
    ShowMessage(IntToStr(I));
    FProc(Sender);
end;

procedure TForm1.FormCreate(Sender: TObject);
var
    F : TFoo;
    I: Integer;
    mi : TMenuItem;
begin
    if Assigned(NE) then FreeAndNil(NE);

    for I := 1 to 10 do
    begin
        F := TFoo.Create;
        F.Bar := 'Hello World!';
        F.Val := I;
        NE := TNotifyEventWrapper.Create
        (
            procedure (Sender :TObject)
            begin
               ShowMessage(F.Bar + ' ' + inttostr(F.Val) + Format('  Addr = %p',[Pointer(F)]) + Format('Sender = %p,MI.OnClick = %p',[Pointer(Sender),Pointer(@TMenuItem(Sender).OnClick)]));
            end
        );
        NE.I := I;

        mi := TMenuItem.Create(PopupMenu1);

        mi.OnClick := NE.Event;

        mi.Caption := inttostr(F.Val);

        PopupMenu1.Items.Add(mi);
    end;
end;

end.

单击菜单项目编号6

该程序显示预期的消息

但是,下一条消息未显示预期结果.

而不是6它显示项目10

无论我点击列表中的哪个项目,它们似乎都会触发列表中最后一项的事件处理程序(10).

有人向我建议NE对象的成员过程Event对于该对象的所有实例都是相同的内存地址.

无论我点击哪个菜单项,内存地址MI.OnClick都是一样的.

解决方法

理解这一点的关键是要理解变量捕获捕获变量而不是值.

你的anon方法都捕获相同的变量F.由于FormCreate只执行一次,因此该变量只有一个实例.这解释了这种行为.当您的匿名方法执行变量时,F在最后的循环迭代中具有赋值给它的值.

您需要的是每个不同的anon方法捕获不同的变量.您可以通过在生成每个不同的anon方法时创建新的堆栈帧来完成此操作.

function GetWrapper(F: Foo): TNotifyEventWrapper;
begin
  Result := TNotifyEventWrapper.Create(
    procedure(Sender: TObject)
    begin
      ShowMessage(F.Bar + ...);
    end
  );
end;

因为函数GetWrapper的参数是该函数的堆栈帧中的局部变量,所以GetWrapper的每次调用都会创建该局部变量的新实例.

您可以将GetWrapper放在任何地方.作为FormCreate中的嵌套函数,或作为私有方法,或在单元范围内.

然后像这样构建菜单：

F := TFoo.Create;
F.Bar := 'Hello World!';
F.Val := I;
NE := GetWrapper(F);
NE.I := I;

delphi – 在pascal中动态分配匿名函数

解决方法

猜你在找的Delphi相关文章